SENSOR-PLUS

ライブラリ

SENSOR-PLUSを利用するためには、以下の３つのライブラリを導入する必要があります。

  • OLEDディスプレイ用ライブラリ
  • 温度・湿度センサーAHT21用ライブラリ
  • 加速度センサーKXTJ3-1057用ライブラリ

OLEDディスプレイのライブラリは、ライブラリマネージャで導入できます。以下のページを参考にして導入してください。

OLEDディスプレイ

温度・湿度センサーのライブラリは、ライブラリマネージャで導入できます。以下のページを参考にして導入してください。

AHT21 気温・湿度センサー

加速度センサーKXTJ3-1057のライブラリは、ライブラリマネージャで導入できます。以下のページを参考にして導入してください。

KXTJ3-1057加速度センサー

ESP32-C3M-SLIMでのプログラム例

この章では、SENSOR-PLUSをESP32-C3M-SLIMに接続して使用する例を示しています。ただし、ここで示しているプログラム例は、ESP32-C3固有の機能を使用していないので、ESP32/ESP32-S3を使用している開発ボードでも、SENSOR-PLUSに接続する端子の接続に注意すれば、同様に使用することができます。

端子の割り当て

ESP32-C3M-SLIMとSENSOR-PLUSの接続は、ESP32-C3M-SLIMのCN2,CN3端子にピンソケットを取り付け、そのピンソケットとSENSOR-PLUSのCN1のピンソケット間でジャンパー線で接続しています。

SENSOR-PLUS
ピンソケット		機能ESP32-C3M-SLIM
ピンソケット		開発ボード
端子
1BRT (明るさセンサー)CN2: 5D2 (A2)
2SND (圧電スピーカー)CN3: 6D21 (TXD)
3GNDCN2: 1GND
45VCN2: 25V
5SCLCN2: 3SCL (D9)
6SDACN2: 4SDA (D8)
73V3-
8SW2CN3: 2D5
9SW1CN3: 3D6
10RGB (WS2812)CN3: 5D20
113V3CN2: 63V3
12GNDCN3: 1GND

OLEDディスプレイへの文字表示

OLEDディスプレイに文字列を表示するスケッチ例を示します。

SENSOR-PLUS のOLEDディスプレイには、コントローラとしてSSD1306が使用されています。OLEDディスプレイの制御ライブラリは、様々なものが提供されていますが、ここではU8g2ライブラリを使用した例を示します。

U8g2 ライブラリの使用法は、以下のWEBページに紹介されています。

ライブラリマネージャを使用してU8g2ライブラリを導入して使用してください。

#include <U8x8lib.h>

U8X8_SSD1306_128X64_NONAME_HW_I2C u8x8(U8X8_PIN_NONE);

void setup() {
  pinMode(21, OUTPUT) ; // 圧電スピーカーのノイズ止め

  u8x8.begin();
  u8x8.setFont(u8x8_font_amstrad_cpc_extended_r);
  u8x8.clearDisplay();
}

char tstr[20];

void loop() {
  u8x8.drawString(1, 0, "- SENSOR-PLUS -");
  u8x8.drawString(4, 1, "MicroFan");
  u8x8.drawString(0, 2, "OLED Display");
  u8x8.drawString(0, 3, "Piezo Speaker");
  u8x8.drawString(0, 4, "Brightness SNSR");
  u8x8.drawString(0, 5, "Temp. Hum. SNSR");
  u8x8.drawString(0, 6, "Accelerometer");
  u8x8.drawString(0, 7, "WS2812 RGB LED");

  delay(1000);
}

スイッチと圧電スピーカー

SW1,SW2を押すと、それぞれ異なる音を鳴らすスケッチ例です。

#define SW1 6
#define SW2 5
#define SND 21

void setup() {
  pinMode(SW1, INPUT) ;
  pinMode(SW2, INPUT) ;
}

void loop() {
  int hz = 0 ;

  if (digitalRead(SW1) == LOW)
     hz += 440 ;
  if (digitalRead(SW2) == LOW)
     hz += 880 ;

  if (hz != 0)
    tone(SND, hz) ;
  else
    noTone(SND) ;

  delay(100) ;
}

気温・湿度・明るさセンサー

OLEDディスプレイに気温・湿度センサーAHT21で得られた気温と湿度と、明るさセンサー（フォトトランジスタ）で得られた明るさを表示するスケッチ例を示します。

SENSOR-PLUSの気温・湿度センサーには、AHT21が使用されています。AHT21の制御には、AHT20用のライブラリを使用することができます。ここでは、Adafruit AHTX0ライブラリを使用した例を示します。ライブラリマネージャを使用してAdafruit AHTX0ライブラリを導入して使用してください。

#include <U8x8lib.h>
#include <Adafruit_AHTX0.h>

U8X8_SSD1306_128X64_NONAME_HW_I2C u8x8(U8X8_PIN_NONE);
Adafruit_AHTX0 aht;

void setup() {
  pinMode(21, OUTPUT) ; // 圧電スピーカーのノイズ止め

  u8x8.begin();
  u8x8.setFont(u8x8_font_amstrad_cpc_extended_r);
  u8x8.clearDisplay();
  aht.begin(); // AHT21の初期化
}

char tstr[20];

void loop() {
  sensors_event_t humidity, temp;

  aht.getEvent(&humidity, &temp); // AHT21から湿度と温度の取得

  u8x8.draw1x2String(0, 0, "TEMP: ");
  dtostrf(temp.temperature, 4, 1, tstr);  // sprintf は実数の変換ができない
  u8x8.draw1x2String(6, 0, tstr);
  u8x8.draw1x2String(10, 0, "'C");
  sprintf(tstr, "%2d%%", (int)humidity.relative_humidity);
  u8x8.draw1x2String(0, 2, "HUM: ");
  u8x8.draw1x2String(5, 2, tstr);
  u8x8.draw1x2String(0, 4, "BRT: ") ;
  dtostrf(analogRead(2)/4095.0, 4, 2, tstr);  // sprintf は実数の変換ができない
  u8x8.draw1x2String(5, 4, tstr);

  delay(1000);
}

加速度センサー

OLEDディスプレイに３軸の加速度と、基板の傾きを表示するスケッチ例を示します。

SENSOR-PLUSの加速度センサーには、XKTJ3-1057が使用されています。ここでは、XKTJ3-1057ライブラリを使用した例を示します。ライブラリマネージャを使用してXKTJ3-1057ライブラリを導入して使用してください。

#include <U8x8lib.h>

U8X8_SSD1306_128X64_NONAME_HW_I2C u8x8(U8X8_PIN_NONE);

// Accelerometer provides different Power modes by changing output bit resolution
#define LOW_POWER
//#define HIGH_RESOLUTION

#include <kxtj3-1057.h>
#include <Wire.h>
#include <math.h>

float sampleRate = 6.25;  // HZ - Samples per second - 0.781, 1.563, 3.125, 6.25, 12.5, 25, 50, 100, 200, 400, 800, 1600Hz
uint8_t accelRange = 2;   // Accelerometer range = 2, 4, 8, 16g

KXTJ3 myIMU(0x0E);  // Address can be 0x0E or 0x0F

void setup() {
  u8x8.begin();
  u8x8.setFont(u8x8_font_amstrad_cpc_extended_r);
  u8x8.clearDisplay();

  pinMode(21, OUTPUT) ; // 圧電スピーカーのノイズ止め

  myIMU.begin(sampleRate, accelRange);

  // Detection threshold, movement duration and polarity
  myIMU.intConf(123, 1, 10, HIGH);
}

char tstr[20];

void loop() {
  float x, y, t ;

  myIMU.standby(false);

  u8x8.draw1x2String(0, 0, "X: ");
  dtostrf(x = myIMU.axisAccel(X), 6, 3, tstr);  // sprintf は実数の変換ができない
  u8x8.draw1x2String(3, 0, tstr);
  u8x8.draw1x2String(0, 2, "Y: ");
  dtostrf(y = myIMU.axisAccel(Y), 6, 3, tstr);
  u8x8.draw1x2String(3, 2, tstr);
  u8x8.draw1x2String(0, 4, "Z: ");
  dtostrf(myIMU.axisAccel(Z), 6, 3, tstr);
  u8x8.draw1x2String(3, 4, tstr);

  t = atan2(-y, x) * 180 / 3.14 ;
  u8x8.draw1x2String(0, 6, "DEG: ");
  dtostrf(t, 6, 1, tstr);
  u8x8.draw1x2String(5, 6, tstr);

  myIMU.standby(true);

  delay(1000);
}

WS2812カラーLED

WS2812はNeoPixelライブラリで操作できます。

NeoPixelライブラリがインストールされると、メニューバーの[ファイル] -> [スケッチ例...]を選択すると、メニューの下の方の[カスタムライブラリのスケッチ例]の中にインストールされたNeoPixelライブラリに関する項目が追加されていることがわかります。

その項目を選択すると、いくつかのデモスケッチが表示されます。

カラーLEDの動作テストとしては、カラーLEDの鮮やかな色の変化を楽しめるstrandtestがよいでしょう。スケッチを開いたら、図に示す様に２つの定数をSENSOR-PULSの接続に合わせて設定します。

#define LED_PIN 20

#define LED_COUNT 3

strandtestをコンパイル・実行させると、SENSOR-PLUSの右側の３個のカラーLEDが、様々に色を変えながら点滅します。